Subject: Re: info on g orbitals and higher angular momentum orbitals

From: Herbert Homeier (t4720) <[email-masked]>
Date: Mon, 11 Apr 94 22:00:39 +0200

> From [email-masked] Sat Apr  2 03:22:46 1994
> Subject: CCL:info on g orbitals and higher angular momentum orbitals
> To: [email-masked]
> X-Mailer: ELM [version 2.4 PL20]
> Content-Type> : > text> 
> Content-Length: 2149
> Sender: [email-masked]
> X-Lines: 49
> 
>  Hi Netters,
> 
>   After spending a good bit of an afternoon trying to find an article
>   that had pictures of g-functions in it, I only found one reference:
>   
>   "Order out of Chaos: Shapes of Hydrogen Orbitals"
>   by G. L. Breneman in J. Chem. Ed., Vol. 65, p.31 (1988).
>   
>   This is a pretty good article, but the pictures are of very poor
>   quality once I photocopy the article.  Can anyone recommend any 
>   other articles or even books that have nice looking pictures of 
>   g-functions.  I would also be interested in any pictures of
>   orbitals with higher angular momentum than 'g' or about any studies   
       ..... (stuff deleted) ....     
>   Russ
>   
>   -- 
>   Russ Thomas
>   Center for Computational Quantum Chemistry
>   University of Georgia, Athens, Georgia   30602-2556
>   [email-masked] : Phone (706) 542-7747 : FAX (706) 542-0406 

Russ,

it is rather easy to generate nice plots of spherical harmonics for higher
l values using for instance Maple V Release 2. Below, I include a short
text file which shows how to do this. 

Best regards

Herbert
--------------------------------------------------------------
Dr. Herbert H. H. Homeier
Institut fuer Physikalische und Theoretische Chemie
Universitaet Regensburg
D-93040 Regensburg, Germany
Phone: +49-941-943 4720                FAX  : +49-941-943 2305
email: [email-masked]    (preferred)
       [email-masked]
       [email-masked]
--------------------------------------------------------------
-------------------- cut here, call orbitals.txt, import as text file ---------
 #45678901234567890123456789012345678901234567890123456789012345678901234567890
 #
 # author and copyright:  Herbert H. H. Homeier, 1994
 # email: [email-masked]
 # date: April 11, 1994
 # 
 # description: procedures to compute real and complex spherical harmonics
 #              and to display them via three-dimensional polar diagrams
 #
 # include plots package
 with(plots);
 # define a procedure for a 3d polar diagram
 pointnr := 4000: # number of points in the plot
 polardiagram:=u -> sphereplot(abs(simplify(u)),phi=0..2*Pi,theta=0..Pi,
              axes=boxed,scaling=constrained,style=point,numpoints=pointnr);
 # define spherical coordinate functions (for r=1)
 x:=(phi,theta)->cos(phi) * sin(theta);
 y:=(phi,theta)->sin(phi)*sin(theta);
 z:=(phi,theta)->cos(theta);
 # plot some cartesian real angular functions
 d_xy:=polardiagram( (x(phi,theta)*y(phi,theta))  ): d_xy;
 p_x:=polardiagram(x(phi,theta)): p_x;
 f_xyz:=polardiagram( (x(phi,theta)*y(phi,theta)) *z(phi,theta) ):f_xyz;
 # define procedures for
 #         associated Legendre function 
 #                     of  simple argument x  
 assLeg:=(l,m,x)->1/2^l/l!*(1-x*x)^abs(m/2)*
                           diff( (x*x-1)^l,seq(x,i=1..(l+abs(m))));
 #                     of complicated argument (for instance z=cos(theta))
 AssLeg:=proc(l,m,z)
 local x;
 simplify(subs(x=z,assLeg(l,m,x)));
 end;
 #         complex spherical harmonics (Condon-Shortley phases)
 spherHarm:=proc(l,m,theta,phi)
   local mm,x;
   mm:=abs(m);
   I**(m+mm)*
     1/2^l/l!*(sin(theta))^mm*
     simplify(
       subs(x=cos(theta),
            diff( (x*x-1)^l,seq(x,i=1..(l+mm)))
           )
       )*
     exp(I*m*phi)*
     sqrt((2*l+1)*(l-mm)!/(l+mm)!/4/Pi);
 end;
 #        real spherical harmonics ( m<0: sin function, else cos function)
 realSpherHarm:=proc(l,m,theta,phi)
 local mm,x;
 mm:=abs(m);
 if m<0 then
   AssLeg(l,mm,cos(theta))*sin(mm*phi)*sqrt((2*l+1)*(l-mm)!/(l+mm)!/2/Pi); 
 else
   AssLeg(l,mm,cos(theta))*cos(mm*phi)*sqrt((2*l+1)*(l-mm)!/(l+mm)!/2/Pi); 
 fi;
 end;
 # create 3d polar diagrams for some real spherical harmonics
 polardiagram(realSpherHarm(3,0,theta,phi));
 # pointnr := 40000: # uncomment for higher resolution of next plot (slower!)
 polardiagram(realSpherHarm(5,2,theta,phi));
 # calculate some complex spherical harmonics
 spherHarm(5,-5,theta,phi);
 spherHarm(5,-4,theta,phi);factor(");
 spherHarm(5,-3,theta,phi);factor(");
 spherHarm(5,-2,theta,phi);factor(");
 spherHarm(5,-1,theta,phi);factor(");
 spherHarm(5,0,theta,phi);factor(");
 spherHarm(5,1,theta,phi);factor(");
 spherHarm(5,2,theta,phi);factor(");
 spherHarm(5,3,theta,phi);factor(");
 spherHarm(5,4,theta,phi);factor(");
 spherHarm(5,5,theta,phi);factor(");
 #   compare A. Lindner, Drehimpulse in der Quantenmechanik
 #           (Teubner, Stuttgart, 1984), p. 97.
 spherHarm(3,3,theta,phi);factor("*sqrt(4*Pi/7));
 spherHarm(3,-3,theta,phi);factor("*sqrt(4*Pi/7));
 spherHarm(3,2,theta,phi);factor("*sqrt(4*Pi/7));
 spherHarm(3,-2,theta,phi);factor("*sqrt(4*Pi/7));
 spherHarm(3,1,theta,phi);factor("*sqrt(4*Pi/7));
 spherHarm(3,-1,theta,phi);factor("*sqrt(4*Pi/7));
 spherHarm(3,0,theta,phi);factor("*sqrt(4*Pi/7));